File:Snake.zip

From Zak
Revision as of 17:20, 1 September 2016 by Admin (Talk | contribs)

Jump to: navigation, search
Snake.zip(file size: 3 KB, MIME type: application/zip)
Warning: This file type may contain malicious code. By executing it, your system may be compromised.

Snake (Matopeli)

File Summary

File Snake (Basic)
Version 1
File size 3 KB
Release date February
Release year 1986
Type Video game
Platform Commodore 64
Requirements
License [[:Finnish games:|]]

Game Summary

Developer Tommi Timonen
Publisher MikroBitti
Original release date
Original release year 1986
Genre Action
Subgenre Snake variant
Series [[:Finnish games:|]]
Article Snake (Basic)
Website {{{Website}}}

Screenshots

Snake Gameplay screen.png
[[Image:|center|300px]]

[[{{{More screenshots}}}|More screenshots]]

Toiminta
Matopeli
Snake.zip
{{{Competition}}}
{{{Tag_featured}}}
{{{Tag_bloody}}}
{{{Tag_level_editor}}}
{{{Tag_multiplayer}}}
{{{Tag_short}}}
Yes
{{{Tag_play}}}
{{{Tag_christmas}}}
{{{Tag_finnish_summer}}}
{{{Platform2}}}
{{{Platform3}}}
{{{Platform4}}}
{{{Platform5}}}
{{{Platform6}}}
{{{Platform7}}}
{{{Platform8}}}
{{{Platform9}}}

README

                            Matopeli
                            (Snake)
                        ================

                         [Commodore 64]

                    Programmer: Tommi Timonen
             Published: MikroBITTI (February 2/86)

                       Language: Finnish

As disgusting as it might sound, I must say: “You’re a big
worm.” Your only task in life is eating.

As you gorge on the numbers appearing on the screen you become
longer and more handsome. The more handsome you become, the
more difficult it becomes to eat numbers. Your speed is so fast
that bumping into things gets life threatening for you. As you
grow in length, it gets easier and easier to bump into the
edges of the screen or into your own tail’s folds.

You control your movements by using buttons I-J-K-M or with
Joystick port 2. 

---------------------------------------------------------------
                             OHJEET
                   (Instructions in Finnish)
---------------------------------------------------------------

Niin inhottavalta kuin se saattaa kuulostaakin on minun sanot-
tava se sinulle suoraan: "Olet suuri mato."

Ainoa elämäntehtäväsi on syöminen. Nauttiessasi kuvaruudulle
ilmestyviä numeroita muutut pidemmäksi ja komeammaksi. Mitä
komeampi sinusta tulee, sitä vaikeammaksi muuttuu uusien nume-
roiden syöminen. Vauhtisi on nimittäin sen verran kova, että
kaikki törmäykset ovat sinulle hengenvaarallisia. Pituutesi
kasvaessa törmäät yhä helpommin joko ruudun reunoihin tai oman
häntäsi poimuihin.

Ohjaat itseäsi näppäimillä I-J-K-M tai joystickillä portissa
kaksi.

---------------------------------------------------------------
                            HUOMIOT
                            (Notes)
---------------------------------------------------------------

Ohjelmalistauksen erikoismerkit ovat muodossa
{clear}, {blue}, jne. ja voidaan muuntaa takaisin esimerkiksi
C64List-ohjelmalla:
http://www.commodoreserver.com/Downloads.asp

The special characters in the program listings are {clear},
{blue}, etc. and can be converted back with – for example –
C64List program:
http://www.commodoreserver.com/Downloads.asp

---------------------------------------------------------------
                         OHJELMALISTAUS
                       (Program Listing)
---------------------------------------------------------------

5 REM TT 06/04/85
10 POKE53280,0:POKE53281,7:PRINT"{clear}{black}"
20 GOTO2000
97 :
98 REM ALKURUTIINIT
99 :
100 DIMP%(1000)
110 PRINT"{clear}{black}{rvrs on}              PISTEET: 000              "
115 FORI=55296TO56295:POKEI,0:NEXT
120 FORA=0TO8:P%(A)=1514+A:POKE1514+A,87:NEXT
130 P%(9)=1523:POKE1523,81
140 E=9:V=0:X=19:Y=11:S=4
150 GOSUB990
197 :
198 REM OHJAUS
199 :
200 A=PEEK(197):IFA=64THEN250
210 IFA=33THENS=1
215 IFA=36THENS=2
220 IFA=34THENS=3
225 IFA=37THENS=4
240 GOTO290
250 A=(NOTPEEK(56320))AND15
260 IFA=0THEN290
270 IFA=1THENS=1
275 IFA=2THENS=2
280 IFA=4THENS=3
285 IFA=8THENS=4
290 X=X+(S=3)-(S=4)
295 Y=Y+(S=1)-(S=2)
300 IFX<0ORX>39ORY<0ORY>23THEN1000
310 POKEP%(E),87:E=E+1:IFE=1000THENE=0
320 P%(E)=1064+X+40*Y:IFPEEK(P%(E))=87THEN1000
325 IFPEEK(P%(E))>128THENGOSUB900
326 POKEP%(E),81
330 IFL=0THENPOKEP%(V),32:V=V+1:IFV=1000THENV=0
340 IFL>0THENL=L-1
400 GOTO200
897 :
898 REM NUMERO
899 :
900 L=PEEK(P%(E))-176
910 POKEP%(E),81
920 SC=SC+L:S$=MID$(STR$(SC),2)
930 IFLEN(S$)<3THENS$="0"+S$:GOTO930
940 PRINT"{home}{right:23}{rvrs on}"S$
950 FORA=54272TO54295:POKEA,0:NEXT
960 POKE54296,15:POKE54277,133:POKE54278,133:POKE54276,17
970 FORA=LTO0STEP-1:POKE54273,150+5*A:FORR=0TO100:NEXT:NEXT
980 POKE54272,0:POKE54273,0:POKE54276,0
990 Z=INT(RND(1)*960)+1064:IFPEEK(Z)<>32THEN990
991 POKEZ,177+INT(RND(1)*8)
995 RETURN
997 :
998 REM LOPPU
999 :
1000 FORA=54272TO54295:POKEA,0:NEXT
1010 POKE54296,15:POKE54277,131:POKE54278,123:POKE54276,33
1020 FORR=0TO50:POKE54273,25+INT(RND(1)*5):NEXT
1030 POKE54272,0:POKE54273,0:POKE54276,0
1040 POKE198,0
1050 POKEZ,32
1060 IFV<ETHENFORA=VTOE:POKEP%(A),32:NEXT:GOTO2000
1070 FORA=VTO999:POKEP%(A),32:NEXT
1080 FORA=0TOE:POKEP%(A),32:NEXT
2000 PRINT"{home}{down:3}{right:15}MATOPELI"
2010 PRINT"{down:3}{right:32}I"
2020 PRINT"{right:6}OHJAA MATOA NAPPAIMILLA  J K"
2030 PRINT"{right:32}M"
2040 PRINT"{down:2}{right:6}TAI JOYSTICKILLA!"
2060 PRINT"{down:4}{right:5}PAINA VALILYONTIA ALOITTAAKSESI!"
2100 POKE198,0
2110 GETA$:IFA$<>""THENRUN100
2120 IF(PEEK(56320)AND16)=0THENRUN100
2130 GOTO2110

---------------------------------------------------------------
 https://zak.fi/                                 July 20, 2015
---------------------------------------------------------------

Similar games

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeDimensionsUserComment
current11:44, 20 July 2015 (3 KB)Admin (Talk | contribs)
  • You cannot overwrite this file.

There are no pages that link to this file.