Difference between revisions of "File:Spider Fight (Oric-1).txt"

From Zak
Jump to: navigation, search
m
m
 
Line 27: Line 27:
 
See also =
 
See also =
 
Katso =
 
Katso =
 +
Tag_source_code = Yes
 
</data>
 
</data>
  

Latest revision as of 17:21, 1 September 2016

Hämähäkkitaistelu (Spider Fight)

File Summary

File Spider Fight
Version 1
File size 9 KB
Release date October
Release year 1984
Type Video game
Platform Oric-1
Requirements
License [[:Finnish games:|]]

Game Summary

Developer Mikko-Petteri Turta
Publisher MikroBitti
Original release date
Original release year [[:Finnish games:|]]
Genre Action
Subgenre Shooter
Series [[:Finnish games:|]]
Article Spider Fight
Website {{{Website}}}

Screenshots

Spider Fight.png
[[Image:|center|300px]]

[[{{{More screenshots}}}|More screenshots]]

Toiminta
Ammuskelu
Spider_Fight_(Oric-1).txt
CompOric1
{{{Competition}}}
{{{Tag_featured}}}
{{{Tag_bloody}}}
{{{Tag_level_editor}}}
{{{Tag_multiplayer}}}
{{{Tag_short}}}
Yes
{{{Tag_play}}}
{{{Tag_christmas}}}
{{{Tag_finnish_summer}}}
{{{Platform2}}}
{{{Platform3}}}
{{{Platform4}}}
{{{Platform5}}}
{{{Platform6}}}
{{{Platform7}}}
{{{Platform8}}}
{{{Platform9}}}

README

                       Hämähäkkitaistelu
                         (Spider Fight)
                       =================

                            [Oric-1]

                Programmer: Mikko-Petteri Turta
             Published: MikroBITTI (October 3/84)

                       Language: Finnish

Spider Fight, a spider fighting game was made for Oric-1. It can
quite easily be converted for other microcomputers. The goal is
to destroy the space spider that flies on the screen as many
times as possible. The spider drops killer satellites, which
the player can’t hit. More detailed instructions come with the
game itself.

---------------------------------------------------------------
                             OHJEET
                   (Instructions in Finnish)
---------------------------------------------------------------

Spider Fight, hämähäkkitaistelu on Oric-1:lle tehty peli, joka
kuitenkin on verrattain helposti sovitettavissa muillekin
mikroille. Pelin tarkoituksena on tuhota kuvaruudulla lentävä
avaruushämähäkki mahdollisimman monta kertaa. Hämähäkki jättää
jälkeensä tappajasatelliitteja, joihin pelaaja ei saa törmätä.
Tarkemmat peliohjeet sisältyvät itse ohjelmaan.

Ohjelmaa muille mikroille kirjoitettaessa on erityisesti
otettava huomioon satunnaiset värit kuvaruudulle valitseva
aliohjelma, joka käyttää hyväkseen Oricin hieman omalaatuista
värigrafiikkaa. Kyseisen aliohjelman voi jättää pois, mutta
silloin peli menettää osan viehätyksestään.

Ohjelmaa kirjoitettaessa kannattaa ilman muuta jättää kaikki
välilyönnit pois rivinumeron tai käskyn jälkeen; se nopeuttaa
ohjelman suoritusta. Lisäsin välit listaukseen vain selvyyden
vuoksi. Rivillä 7030 tulee lainausmerkkien sisään 37 kpl
}-aaltosulkuja.

---------------------------------------------------------------
                         OHJELMALISTAUS
                       (Program Listing)
---------------------------------------------------------------

1 REM================================
2 REM         SPIDER FIGHT
3 REM 17.4.-84 by Mikko-Petteri Turta
4 REM================================
5 REM
6 GOSUB5000
7 LORES0:CLS:PAPER0:INK6
8 GOSUB7000
9 H$="HERRA HUU":CLS:INPUT"ANNA VAIKEUSTASO (10-30, 30 helpoin)";SK%
10 IFSK%<10ORSK%>30THEN9
11 PRINT"ONKO N<PP<IMIST>SI MERKKI<<NI P<<LL< (K/E) ?":GETA$
12 IFA$="K"THENPRINTCHR$(6)
13 PRINT"ONKO KURSORISI P<<LL< (K/E) ?":GETA$
14 IFA$="K"THENPRINTCHR$(17)
15 BB=SK%
20 SC%=0:L%=2
30 X2%=3:Y2%=3
50 AM%=10:V%=0:X%=19:Y%=13:A%=3:B%=3:S%=3:CLS
60 GOSUB6000
100 REM}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
105 REM
110 REM------------------------------
120 REM   MUUKALAINEN LIIKKUU
130 REM------------------------------
140 Q%=INT(RND(1)*5)+1
150 IFQ%=5THENW%=-1
160 IFQ%=4THENW%=1
170 IFQ%=3THENE%=-1
180 IFQ%=2THENE%=1
190 C%=A%:D%=B%
200 A%=A%+W%:IFA%=38THENA%=3
210 IFA%=2THENA%=37
220 B%=B%+E%:IFB%=27THENB%=0
230 IFB%=-1THENB%=26
240 PLOTC%,D%,32:PLOTC%+1,D%,32
250 PLOTA%,B%,91:PLOTA%+1,B%,93
260 R=RND(1)*SK%:IFR<4THENPLOTC%,D%,125
270 REM------------------------------
280 REM      OMA LIIKKUU/AMPUU
290 REM------------------------------
295 MUSIC1,1,4,0:PLAY7,0,4,200
300 K$=KEY$
305 M%=0
310 IFK$=CHR$(11)THENM%=-1
320 IFK$=CHR$(9)THENM%=1
322 IFK$=CHR$(32)ANDAM%>0THENPLOTX2%,Y2%,32
325 IFK$=CHR$(32)ANDAM%>0THENV%=1:AM%=AM%-1:X2%=X%:Y2%=Y%:AS%=S%
330 S%=S%+M%
335 IFS%=9THENS%=1
336 IFS%=0THENS%=8
340 0%=X%:P%=Y%
350 IFS%=1THENY%=Y%-1
360 IFS%=2THENY%=Y%-1:X%=X%+1
370 IFS%=3THENX%=X%+1
380 IFS%=4THENX%=X%+1:Y%=Y%+1
390 IFS%=5THENY%=Y%+1
400 IFS%=6THENY%=Y%+1:X%=X%-1
410 IFS%=7THENX%=X%-1
420 IFS%=8THENX%=X%-1:Y%=Y%-1
430 IFX%=37THENX%=3
440 IFX%=2THENX%=37
450 IFY%=-1THENY%=26
460 IFY%=27THENY%=0
480 IFS%=1THENN$="{"
485 IFS%=2THENN$="_"
490 IFS%=3THENN$="#"
495 IFS%=4THENN$="\"
500 IFS%=5THENN$="@"
505 IFS%=6THENN$=":"
510 IFS%=7THENN$="^"
515 IFS%=8THENN$="&"
516 K=0
520 PLOTO%,P%,32
525 IFSCRN(X%,Y%)>34THENK=1
530 PLOTX%,Y%,N$
535 IFK=1THEN2120
540 IFV%=0ANDAM%=0THENGOTO2000
600 IFV%=0THEN140
610 REM------------------------------
620 REM          OHJUS
630 REM------------------------------
631 T=1
635 X3%=X2%:Y3%=Y2%
640 IFAS%=1THENY2%=Y2%-1
650 IFAS%=2THENY2%=Y2%-1:X2%=X2%+1
660 IFAS%=3THENX2%=X2%+1
665 IFAS%=4THENX2%=X2%+1:Y2%=Y2%+1
670 IFAS%=5THENY2%=Y2%+1
675 IFAS%=6THENY2%=Y2%+1:X2%=X2%-1
680 IFAS%=7THENX2%=X2%-1
685 IFAS%=8THENX2%=X2%-1:Y2%=Y2%-1
690 IFX2%=2THENX2%=3:V%=0
692 IFX2%=38THENX2%=37:V%=0
694 IFY2%=-1THENY2%=0:V%=0
695 IFY2%=27THENY2%=26:V%=0
700 PLOTX3%,Y3%,32
705 IFV%=0THEN140
706 IFSCRN(X2%,Y2%)=125THEN2500
708 IFSCRN(X2%,Y2%)=91ORSCRN(X2%,Y2%)=93THEN3000
710 PLOTX2%,Y2%,33
720 IFT=1THENT=0:GOTO635
750 GOTO140
2000 REM------------------------------
2010 REM   KUN OHJUKSET LOPPUVAT
2020 REM------------------------------
2025 G=0
2030 C%=A%:D%=B%
2040 IFA%<X%THENA%=A%+1
2050 IFA%>X%THENA%=A%-1
2060 IFB%<Y%THENB%=B%+1
2070 IFB%>Y%THENB%=B%-1
2080 PLOTC%,D%,32:PLOTC%+1,D%,32
2090 IF(A%=X%ANDB%=Y%)OR(A%+1=X%ANDB%=Y%)THENG=1
2100 PLOTA%,B%,91:PLOTA%+1,B%,93
2110 IFG=0THEN2030
2120 EXPLODE:WAIT400:IFL%>1THENL%=L%-1:GOTO50
2130 GOTO4000
2499 REM------------------------------
2500 V%=0:PLOTX2%,Y2%,42:MUSIC1,2,6,15:WAIT10:MUSIC1,2,6,0
2510 PLOTX2%,Y2%,32:GOTO140
2999 REM------------------------------
3000 V%=0:SC%=SC%+1:SHOOT:WAIT30:PLOTX2%,Y2%,32:PLOTX2%+1,Y2%,32
3005 PLOTX2%-1,Y2%,32:PLOTX%,Y%,32
3010 AM%=10:A%=3:B%=3:X%=19:Y%=13:S%=5
3015 GOSUB6500
3020 GOTO140
4000 REM------------------------------
4010 REM         LOPPU
4020 REM------------------------------
4030 IFEN%>=SC%THEN4100
4040 CLS:PRINT"TEIT UUDEN ENN<TYKSEN"
4050 PRINT:INPUT"MIK< NIMESI ON ";H$
4060 EN%=SC%
4100 CLS:PRINT
4110 PRINT"Onnistuit tuhoamaan h<m<h<kin",SC%
4120 PRINT"kertaa. Enn<tys on "EN%". Sen teki":PRINTH$
4125 PRINTCHR$(4)
4130 PRINT:PRINT:PRINT:PRINT:PRINTSPC(11);CHR$(27);"N";CHR$(27);"BGAME OVER"
4135 PRINTCHR$(4)
4136 SK%=BB
4140 PRINT:PRINT:PRINT"HALUATKO PELATA UUDELLEEN (K/E) ?":PING:GETY$
4145 IFY$<>"K"ANDY$<>"E"THEN4140
4150 IFY$="K"THEN20
4160 GOSUB7000
4170 CLS:END
4999 REM
5000 REM------------------------------
5010 REM GRAFIIKKAMERKKIEN M<<RITTELY
5020 REM------------------------------
5030 REM
5040 FORF=47080TO47087:READA:POKEF,A:NEXT
5050 DATA33,18,12,30,30,12,18,33
5060 FORF=46592TO46599:READA:POKEF,A:NEXT
5070 DATA62,28,28,8,8,8,0,0
5080 FORF=46360TO46367:READA:POKEF,A:NEXT
5090 DATA0,32,56,63,56,32,0,0
5100 FORF=46832TO46839:READA:POKEF,A:NEXT
5110 DATA0,1,7,63,7,1,0,0
5120 FORF=46384TO46391:READA:POKEF,A:NEXT
5130 DATA0,0,32,24,31,14,12,8
5140 FORF=46840TO46847:READA:POKEF,A:NEXT
5150 DATA0,0,1,6,62,28,12,4
5160 FORF=46816TO46823:READA:POKEF,A:NEXT
5170 DATA4,12,28,62,6,1,0,0
5180 FORF=47072TO47079:READA:POKEF,A:NEXT
5190 DATA8,12,14,31,24,32,0,0
5200 FORF=46808TO46815:READA:POKEF,A:NEXT
5210 DATA1,27,39,15,19,33,0,0
5220 FORF=46824TO46831:READA:POKEF,A:NEXT
5230 DATA32,54,57,60,50,33,0,0
5240 FORF=47064TO47071:READA:POKEF,A:NEXT
5250 DATA0,0,8,8,8,28,28,62
5260 FORF=46344TO46351:READA:POKEF,A:NEXT
5270 DATA0,0,0,4,0,0,0,0
5280 FORF=46560TO46567:READA:POKEF,A:NEXT
5290 DATA20,0,8,20,34,62,34,0
5300 FORF=46576TO46583:READA:POKEF,A:NEXT
5310 DATA20,0,28,34,34,34,28,0
5320 RETURN
6000 REM------------------------------
6010 REM  SATUNNAISET V<RIT
6020 REM------------------------------
6030 REM
6040 FORF=0TO26
6050 Z=INT(RND(1)*7)+1
6060 PLOT0,F,Z
6070 NEXT
6100 RETURN
6500 REM------------------------------
6510 REM   VAIKEUSTASON MUUTOS
6520 REM------------------------------
6530 AV%=SC%*5+5
6540 IFSK%<=AV%THENRETURN
6550 SK%=SK%-5:RETURN
7000 REM------------------------------
7010 REM      ALKUTEKSTIT
7020 REM------------------------------
7025 CLS:PRINT
7030 PRINT"}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}"
7040 PRINTCHR$(4):PRINTSPC(10);CHR$(27);"N";CHR$(27);"ASPIDER FIGHT"
7045 PRINTCHR$(4)
7050 PRINT"}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}"
7060 PRINT:PRINT" SPIDER FIGHT on peli, jossa sinun"
7070 PRINT"t<ytyy omalla h<vitt<j<ll<si tuhota"
7080 PRINT"Maahan hy>k<nnyt avaruush<m<h<kki mahdollisimman monta kertaa."
7090 PRINT"Se ei voi ampua sinua mutta j<tt<<"
7100 PRINT"j<lkeens< paikallaan leijuvia tappa-"
7110 PRINT"jasatelliitteja, joihin et saa t>rm<-"
7120 PRINT"t< tai tuhoudut. Sinulla on kymmenen"
7130 PRINT"ohjusta, joilla yrit<t osua h<m<h<k-"
7140 PRINT"kiin. Kun ne loppuvat, se k<ytt<<"
7150 PRINT"tilaisuutta hyv<kseen ja hy>kk<< suo-"
7160 PRINT"raan sinua kohti ja tuhoaa sinut, jolloin peli loppuu."
7161 PRINT"Jos ammut uudelleen ennen kuin edel-"
7162 PRINT"linen ohjus on h<ipynyt, t<m< edelli- nen ohjus katoaa."
7163 PRINT"Yhdess< peliss< sinulla on k<ytett<- viss<si kaksi h<vitt<j<<."
7170 PRINTCHR$(27);"L            PAINA N<PP<INT<"
7172 FORF=1TO12
7173 MUSIC1,1,F,5:NEXT
7174 K$=KEY$:IFK$<>""THEN7175ELSEGOTO7172
7175 PLAY0,0,0,0:CLS
7180 PRINT"    ohjausn<pp<imet:"
7190 PRINT:PRINT"kursori yl>s.......k<<nn>s vasemmalle"
7200 PRINT"kursori oikealle...k<<nn>s oikealle"
7210 PRINT"v<lily>nti.........tulitus"
7220 PRINT:PRINTCHR$(27);"L       PAINA V<LILY>NTI<":GETA$
7225 IFA$=" "THEN10
7230 RETURN
9999 REM}}}}}}}}}}}}}}}}}}}}}}}}}}}}}

---------------------------------------------------------------
 https://zak.fi/                                  May 12, 2015
---------------------------------------------------------------

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeDimensionsUserComment
current06:53, 12 May 2015 (9 KB)Admin (Talk | contribs)
11:31, 4 May 2015 (9 KB)Admin (Talk | contribs)
  • You cannot overwrite this file.

There are no pages that link to this file.